89 lines (68 with data), 3.7 kB

#include "../../libdef.any"

// This is a Wilke Spine Pressure Validation Model. To see the documentation click the link below. 
// #path HTML_DOC "<ANYBODY_PATH_BODY>/Documentation/auto_examples/Validation/plot_WilkeSpinePressure.html"

Main = {
	
	AnyDrawOverlayImage wilke = 
  {
    Opacity = 1.0;
    ImageFile = "wilke et al., 2001 Fig3e.jpg";
  };
  
  /**Execute this operation to run the model in the intended operation sequence.  
  It is also possible to run operations seperately, by manual selections in the operation tree*/
  AnyOperationSequence RunApplication = {

    /**This operation calibrates the muscles in the model if these are of the type AnyMuscleModel3E.
    This will just be an empty operation if the model is using a muscle type that does not require calibration.*/
    AnyOperation &CalibrationAnal = Main.HumanModel.Calibration.CalibrationSequence;  

    ///This operation is the inverse dynamic analysis
    AnyOperation &InvAnal=Main.Study.InverseDynamics;
  };

  // ----------------------------------------------------------
  // Draw settings
  // ----------------------------------------------------------
  #include "DrawSettings.any"
  // ----------------------------------------------------------
  // Definition of the path for Mannequin.any file
  // ----------------------------------------------------------  
  #include "Mannequin.any"
  // ----------------------------------------------------------
  // Definition of the path for anthropometric data
  // ----------------------------------------------------------   
  #path BM_SCALING_ANTHRO_FILE "AnyManUniform.any"
  // ----------------------------------------------------------
  // Scaling method settings
  // ----------------------------------------------------------    
  #define BM_SCALING _SCALING_UNIFORM_
  // ----------------------------------------------------------
  // BM statements which configure the structure of human model
  // ----------------------------------------------------------  
  #define BM_LEG_MODEL _LEG_MODEL_TLEM2_
  
  #include "<ANYBODY_PATH_BODY>/HumanModel.any"
  
  // This folder collects the elements of the model. It is referred by the
  // study section below as the target of the analyses.  
  AnyFolder Model={
    
    AnyFolder &BodyModel=.HumanModel.BodyModel;
    AnyFolder &Mannedriver = .HumanModel.BodyModelWithDefaultDrivers.Drivers;

    
    #include "Environment.any"   
    
    // The Mannequin file specifies load-time positions for all the segments
    // in the HumanModel. This is important for the model's ablity to resolve
    // all the kinematic constraints when the model is analyzed.
    // The mannequin file also drives those degrees of freedom of the human 
    // model that are not governed by problem-specific drivers at run time.    
    AnyFolder& Mannequin = .HumanModel.Mannequin;
    
    AnyFolder ModelEnvironmentConnection = {
      #include "JointsAndDrivers.any"
    };
    
  };
  AnyBodyStudy Study = {
    AnyFolder &Model = .Model;
    InitialConditions.SolverType = KinSolOverDeterminate;
    Kinematics.SolverType = KinSolOverDeterminate;
   
    tEnd = 1.0;
    Gravity = {0.0001, -9.81, 0.0001};
    nStep = 1;
	
	//Size of total force in the L5 Sacrum joint
    AnyVar L5SacrumReac = (Main.Model.BodyModel.Trunk.JointsLumbar.L5SacrumJnt.Constraints.Reaction.Fout[0]^2+
    Main.Model.BodyModel.Trunk.JointsLumbar.L5SacrumJnt.Constraints.Reaction.Fout[1]^2+
    Main.Model.BodyModel.Trunk.JointsLumbar.L5SacrumJnt.Constraints.Reaction.Fout[2]^2)^0.5;   
    
  }; // End of study
  
}; //Main