51 lines (42 with data), 2.0 kB

// This is the first calibration file. It will calibrate all the ligaments in the 
// lumbar spine, further sequences will overwrite some values

AnyFolder LumbarLigCal0 ={
  AnyComponentDefinition obj = {};  
  AnyFolder &ThoraxSegs =  ...BodyModel.Trunk.SegmentsThorax;
  AnyFolder &LumbarSegs =  ...BodyModel.Trunk.SegmentsLumbar;
  AnyFolder &SpineLigaments =  ...BodyModel.Trunk.LumbarSpineLigaments;
  
  AnyFixedRefFrame ground = {
    AnyRefNode node = { 
      ARel=.....BodyModel.Trunk.SegmentsThorax.T12Seg.Axes0; 
      sRel=.....BodyModel.Trunk.SegmentsThorax.T12Seg.r0;
    };
  };  
  AnySphericalJoint ThoraxGround={
    AnyRefFrame &Ground = .ground.node;
    AnyRefFrame &Sacrum= ....BodyModel.Trunk.SegmentsThorax.T12Seg;
  };
  
  AnyKinEqSimpleDriver  ThoraxGroundDriver = {
    AnySphericalJoint &Jnt = .ThoraxGround;
    DriverPos = {0,0,0};
    DriverVel = {0,0,0};
    Reaction.Type = {Off,Off,Off}; 
  };
  
  AnyKinEqSimpleDriver AllRelevantJoints = {
      AnySphericalJoint &u1 = ....BodyModel.Trunk.JointsLumbar.SacrumPelvisJnt;
      AnySphericalJoint &u2 = ....BodyModel.Trunk.JointsLumbar.L5SacrumJnt;
      AnySphericalJoint &u3 = ....BodyModel.Trunk.JointsLumbar.L4L5Jnt;
      AnySphericalJoint &u4 = ....BodyModel.Trunk.JointsLumbar.L3L4Jnt;
      AnySphericalJoint &u5 = ....BodyModel.Trunk.JointsLumbar.L2L3Jnt;
      AnySphericalJoint &u6 = ....BodyModel.Trunk.JointsLumbar.L1L2Jnt;
      AnySphericalJoint &u7 = ....BodyModel.Trunk.JointsLumbar.T12L1Jnt;
      DriverPos = {0,0,0, 0,0,0, 0,0,0, 0,0,0, 0,0,0, 0,0,0, 0,0,0};
      DriverVel = {0,0,0, 0,0,0, 0,0,0, 0,0,0, 0,0,0, 0,0,0, 0,0,0};
      Reaction.Type = {On,On,On, On,On,On, On,On,On, On,On,On, On,On,On, On,On,On, On,On,On};
    };
};

// The study: Operations to be performed on the model
AnyBodyCalibrationStudy LumbarLigCalibrationStudy0 = {
  MechObjectExclude={&Main.HumanModel.BodyModel.Trunk.SegmentsCervicalSpine.SkullSeg};
  AnyFolder &ref=.LumbarLigCal0; 
  nStep = 1;
};