115 lines (93 with data), 3.7 kB

AnyFolder HamstringCal ={
  AnyComponentDefinition obj = {};  

  AnyFolder &Pelvis = ...HumanFolderRef.Trunk.SegmentsLumbar.PelvisSeg;
  AnyFolder &Sacrum = ...HumanFolderRef.Trunk.SegmentsLumbar.SacrumSeg;
  
  AnyFolder &LegSegSide = .SideHumanFolderRef.Leg.Seg;
  
  AnyFolder &LegJointsSide = .SideHumanFolderRef.Leg.Jnt;
  AnyFolder &SacrumPelvisJnt = ...HumanFolderRef.Trunk.JointsLumbar.SacrumPelvisJnt;
  
  
  AnyFixedRefFrame ground = {
    AnyRefNode node = {
      ARel=..Pelvis.Axes0;
      sRel=..Pelvis.r0;
    };
  };
  
  AnyKinEq PelvisFix = {
    AnyKinLinear PelvisSacrumLinFix = {
      AnyRefFrame &ground = ..ground.node;
      AnyRefFrame &Pelvis = .....HumanFolderRef.Trunk.SegmentsLumbar.PelvisSeg;
    };
    AnyKinRotational PelvisSacrumRotFix = {
      Type = RotAxesAngles;
      AnyRefFrame &ground = ..ground.node;
      AnyRefFrame &Pelvis = .....HumanFolderRef.Trunk.SegmentsLumbar.PelvisSeg;
    };
  };
  
  AnyKinEqSimpleDriver PelvisSacrumFix = {
    AnyKinMeasure& Jnt = .SacrumPelvisJnt;
    DriverPos = {0,0,0};
    DriverVel = {0,0,0};
    Reaction.Type = {Off,Off,Off};
  };
  
  AnyKinEqInterPolDriver Hip = {
    AnyKinRotational &Spherical = ..SideInterfaceFolderRef.HipFlexion.HipMeasure;
    Type = PiecewiseLinear;
    T =      {0.0, 1.0 };
    Data = { {-20,  110},
             {0,  0},
             {0,  0}
    }*pi/180; // Flexion - Abduction - internal rotation 
    
    Reaction.Type = {Off, Off, Off};
  };
  
  AnyKinEqInterPolDriver Knee = {
    AnyKinMeasure& Hinge = ..SideInterfaceFolderRef.KneeFlexion;
    Type = PiecewiseLinear;
    T =      {0.0, 1.0 };
    Data = {{150,0}}*pi/180; // ? degrees knee flexion
    Reaction.Type = {Off};
  };
  
  
  AnyKinEqInterPolDriver Ankle = {
    AnyKinMeasure& Hinge = ..SideInterfaceFolderRef.AnklePlantarFlexion;
    Type = PiecewiseLinear;
    T =      {0.0, 1.0 };
    Data = {{40,40}}*pi/180;
    Reaction.Type = {Off};
  };
  
  AnyKinEqInterPolDriver SubTalar = {
    AnyKinMeasure& Hinge = ..SideInterfaceFolderRef.SubTalarEversion;
    Type = PiecewiseLinear;
    T =      {0.0, 1.0 };
    Data = {{0,0}}*pi/180;
    Reaction.Type = {Off};
  };
  
  AnyString MusPrefix = CompleteNameOf(&.SideHumanFolderRef.Leg.Mus);
  
  AnyObjectPtrArray BicepsFemorisMuscles = ObjSearch(MusPrefix+".BicepsFemoris*", "AnyMuscle");
  AnyFloat  BicepsFemorisRmin = repmat(NumElemOf(BicepsFemorisMuscles), 0.5);
  AnyFloat  BicepsFemorisRmax = repmat(NumElemOf(BicepsFemorisMuscles), 1.2);
  
  AnyObjectPtrArray SemimembranosusMuscles = ObjSearch(MusPrefix+".Semimembranosus*", "AnyMuscle");
  AnyFloat  SemimembranosusRmin = repmat(NumElemOf(SemimembranosusMuscles), 0.5);
  AnyFloat  SemimembranosusRmax = repmat(NumElemOf(SemimembranosusMuscles), 1.2);
  
  AnyObjectPtrArray SemitendinosusMuscles = ObjSearch(MusPrefix+".Semitendinosus*", "AnyMuscle");
  AnyFloat  SemitendinosusRmin = repmat(NumElemOf(SemitendinosusMuscles), 0.5);
  AnyFloat  SemitendinosusRmax = repmat(NumElemOf(SemitendinosusMuscles), 1.2);
  
  
};

// The study: Operations to be performed on the model
AnyBodyCalibrationStudy LegCalibrationStudyHamstring = {
  AnyFolder &ref=.HamstringCal; 
  nStep = 2;
  MuscleArr = arrcat(
      ref.BicepsFemorisMuscles,
      ref.SemimembranosusMuscles,
      ref.SemitendinosusMuscles
  );
  RminMuscleFiber = arrcat(
      ref.BicepsFemorisRmin,
      ref.SemimembranosusRmin,
      ref.SemitendinosusRmin
  );
  RmaxMuscleFiber = arrcat(
      ref.BicepsFemorisRmax,
      ref.SemimembranosusRmax,
      ref.SemitendinosusRmax
  );
  InitialConditions.SolverType = KinSolOverDeterminate;
};